Hallo zusammen,
ich bin Access-Anfänger und benötige dringend rat und Hilfe bei folgendem Problem:
- ich habe eine Access Datenbank welche immer geöffnet ist
- ein anderes Programm empfängt Daten und kann diese mittels einer Batch als Parameter weitergeben
- die Batchdatei wird so "C:\Batchdatei.bat %1 %2 %3" aufgerufen, die %1 .... sind die Parameter
- ich möchte jetzt diese Parameter in die geöffnete Access Datenbank in Tabelle1, Parameter %1 in Spalte 1 eintragen, %2 in Spalte 2 usw.
Bis jetzt habe ich erfolglos nach einer Lösung gesucht und da ich des programmierens, in welcher Sprache auch immer, nicht mächtig bin benötige ich hier Eure Hilfe.
Wer hat Interesse und Lust mir bei diesem Problem zu helfen?
Es handelt sich bei deisem Projekt im Übrigen um eine Datenbank, welche bei unserer Freiwilligen Feuerwehr zur Abarbeitung von Unwettereinsätzen eingesetzt werden soll.
Vielen Dank
Hallo
1. Erstelle dir ein vb-script, speichere es unter einem dir aussagekräftigen namen z.B. C:\BatchImport.vbs.
Dieses Bsp unten arbeitet imo nur mit 3 Parametern.
Option Explicit
'// ----------------------------------------------------------------------------------------------------------------
'//
'// ----------------------------------------------------------------------------------------------------------------
Const sFile = "X:\Pathwohin\AccessFile.mdb" '<--- Anpassen > Path zur Access-DB
Const sDBE = "DAO.DBEngine.36" '<--- Anpassen >
Const SQL = "Select F1, F2, F3 From Tabelle1;" '<--- Anpassen > F1, F2, F3 sind die Feldnamen
'// ----------------------------------------------------------------------------------------------------------------
'//
'// ----------------------------------------------------------------------------------------------------------------
dim a, b
dim dbe, db, rs
Dim i
Set a = Wscript.Arguments
Set dbe = CreateObject(sDBE)
if not dbe is Nothing then
Set db = dbe.OpenDatabase(sFile)
if not db is Nothing then
Set rs = db.OpenRecordset(SQL)
i = 0
rs.AddNew
for each b in a
if i > 2 then exit for
rs(i) = b
i = i + 1
next
rs.update
rs.close
db.close
end if
end if
Set rs = Nothing
Set DB = Nothing
Set DBE = Nothing
2. Editiere deine Batch-Datei und füge folgende Zeile an:
C:\BatchImport.vbs %1 %2 %3
Solltest du in einer 64 -bit Umgebung arbeiten wird der Code so wahrscheinlich nicht laufen.
Hallo,
tut mir Leid das ich erst jetzt antworten kann.
Vielen Dank für Deine Hilfe.
Ich habe das jetzt getestet und kann Dir sagen, es klappt einwandfrei.
Ich hoffe ich bekomme den Rest jetzt auch noch gebacken.
Vielen Dank