rst.FindFirst Kriterium Ja/Nein = True

[Frank77]

Hallo!

Ich habe ein Unterformular in den ich Logos anzeigen lasse und darunter ist ein Kontrollkästchen mit dem ich das Logo als Standard firmenlogo markieren möchte was aber immer nur eins sein darf

Beim ändern des Kontrollkästchen möchte ich eine abfrage machen ob schon ein Logo mit True markiert ist den es darf nur ein Datensatz markiert sein
Nur bekomme ich das mit dem wert True als Kriterium nicht hin

^{rst.FindFirst "[Logo_Firma_IDRef] = " & Me!txt_Logo_Firma_IDRef And "[Logo_Firma] = -1" 'bzw True}

Gruß Frank

[bahasu]

Hi,

Unter der Voraussetzung, dass das erste Feld eine Zahl ist, wobei mich allerdings "txt_" irritiert:
rst.FindFirst "[Logo_Firma_IDRef] = " & Me!txt_Logo_Firma_IDRef & " And [Logo_Firma] = True"


Falls Text:
rst.FindFirst "[Logo_Firma_IDRef] = '" & Me!txt_Logo_Firma_IDRef & "' And [Logo_Firma] = True"


Harald

[Frank77]

Hallo!

Danke für die hilfe!
Das Txt ist nur ein unsichtbaresfeld das den wert enthält das kann ich ja noch ausfeilen und die werte aus dem aktuelen datensatz auslessen

<sub>Private Sub crk_Logo_Firma_BeforeUpdate(Cancel As Integer)
    Dim rst As Recordset
    Dim FirmaID As Long
    Dim LogoID As Long
    Dim Msg As String
    Dim strSQL As String

    On Error GoTo Err_crk_Logo_Firma

    FirmaID = Me!txt_Logo_Firma_IDRef
    LogoID = Me!txt_Logo_ID

    strSQL = "UPDATE tbl_Logo SET tbl_Logo.Logo_Firma = False " & _
             "WHERE Logo_ID <> " & LogoID & " And Logo_Firma_IDRef = " & FirmaID

    Set rst = Me.RecordsetClone
    rst.FindFirst "[Logo_Firma_IDRef] = " & FirmaID & " And [Logo_Firma] = True"
    If rst.NoMatch Then
        GoTo Exit_crk_Logo_Firma
    Else
        If rst!Logo_ID = LogoID Then GoTo Exit_crk_Logo_Firma
        Msg = "Es wurde ein Standart Logo bereits festgelegt !" & vbCr & "" & vbCr & "Möchten Sie dieses als Standart Logo Festlegen ?"
        Select Case MsgBox(Msg, vbInformation Or vbYesNo Or vbDefaultButton2, "Vorhanden !")
        Case vbYes
            ' Ja
            DoCmd.SetWarnings False
            CurrentDb.Execute strSQL, dbFailOnError
            DoCmd.SetWarnings True
        Case vbNo
            ' Nein
            Me.Undo
            GoTo Exit_crk_Logo_Firma
        End Select
    End If
Exit_crk_Logo_Firma:
    If Not rst Is Nothing Then rst.Close: Set rst = Nothing
    Exit Sub
Err_crk_Logo_Firma:
    Me.Undo
    MsgBox Err.Description
    Resume Exit_crk_Logo_Firma
End Sub</sub>

[MaggieMay]

Hallo,

ein Kontrollkästchen mit dem ich das Logo als Standard firmenlogo markieren möchte was aber immer nur eins sein darf

das löst du am einfachsten mit einer Optionsgruppe.